Luce packages
LuceLuce BaseLuciaOS

dymokomi/luce-3d

Source of release 0.9.5

0.9.5 / shaders / radix_scan.comp

// LSD radix sort, pass step 2: the exclusive scan, in place, of the
// digit-major histogram (16 entries per tile) in one workgroup: entry
// (digit, tile) becomes where that tile's keys of that digit start.
#version 450
layout(local_size_x = 1024) in;
layout(std430, binding = 0) buffer Histogram { uint histogram[]; };
layout(std430, binding = 1) readonly buffer Arguments { uint arguments[]; };

shared uint sums[1024];

void main() {
    uint local = gl_LocalInvocationID.x;
    uint entries = arguments[4] * 16u;
    uint per = (entries + 1023u) / 1024u;
    uint first = min(local * per, entries);
    uint end = min(first + per, entries);
    uint own = 0u;
    for (uint e = first; e < end; e++) own += histogram[e];
    sums[local] = own;
    barrier();
    for (uint step = 1u; step < 1024u; step <<= 1u) {
        uint value = sums[local];
        if (local >= step) value += sums[local - step];
        barrier();
        sums[local] = value;
        barrier();
    }
    uint running = sums[local] - own;
    for (uint e = first; e < end; e++) {
        uint value = histogram[e];
        histogram[e] = running;
        running += value;
    }
}