Luce packages
LuceLuce BaseLuciaOS

dymokomi/luce-cad

Source of release 0.9.3

0.9.3 / tests / contracts / display_error_contract.lucb

## Deviation is geometric, not UV-barycentric correspondence across a diagonal.
## Uneven parameter speed on a plane cannot invalidate an exact planar quad.
from luce_geocore.geocore import Vector3, MeshBuilder, invalid
from geometry import Surface, surface_point
from meshing import validate_display_error

pub func display_error_contract() -> !:
    for scale in [0.001, 1.0]:
        for swapped in [false, true]:
            for reverse in [false, true]:
                for curved in [false, true]:
                    for weighted in [false, true]: try check(scale, swapped, reverse, curved, weighted)

func check(scale: f64, swapped: bool, reverse: bool, curved: bool, weighted: bool) -> !:
    var controls = [Vector3(), Vector3(), Vector3(), Vector3(), Vector3(), Vector3()]
    var weights: f64[6]
    for u in 0..<(usize)3:
        for v in 0..<(usize)2:
            let index = v * 3 + u if swapped else u * 2 + v
            controls[index] = Vector3([0.0, 0.1, 1.0][u], (f64)v, 0.3 if curved and u == 1 else 0.0).multiply_scalar(scale).add(Vector3(3.0, -7.0, 11.0))
            weights[index] = 3.0 if weighted and u == 1 else 1.0
    let ku = [0.0, 0.0, 0.0, 1.0, 1.0, 1.0]
    let kv = [0.0, 0.0, 1.0, 1.0]
    let surface = try Surface(3, Vector3(), Vector3(), Vector3(), 0.0, 0.0, controls, weights,
                              kv[..<kv.length] if swapped else ku[..<ku.length], ku[..<ku.length] if swapped else kv[..<kv.length],
                              2 if swapped else 3, 3 if swapped else 2, 1 if swapped else 2, 2 if swapped else 1)
    defer surface.close()
    var chart = try MeshBuilder(precise = true)
    defer chart.close()
    var lifted = try MeshBuilder(precise = true)
    defer lifted.close()
    for uv in [Vector3(), Vector3(1.0, 0.0, 0.0), Vector3(1.0, 1.0, 0.0), Vector3(0.0, 1.0, 0.0)]:
        _ = try chart.point(uv)
        _ = try lifted.point(try surface_point(surface, uv))
    try chart.face(4)
    try lifted.face(4)
    for at in 0..<(i64)4:
        try chart.corner(3 - at if reverse else at)
        try lifted.corner(3 - at if reverse else at)
    try chart.set_last_display([0, 1, 2, 0, 2, 3])
    try lifted.set_last_display([0, 1, 2, 0, 2, 3])
    let uv_mesh = try chart.finish()
    defer uv_mesh.release()
    let mesh = try lifted.finish()
    defer mesh.release()
    var rejected = false
    validate_display_error(mesh.value(), uv_mesh.value(), surface, scale * 1e-6, 16) catch failure:
        if failure.code != invalid: error(failure.code, failure.message)
        rejected = true
        recover ()
    if rejected != curved: error(invalid, "deviation must accept an exact nonlinear-parameter plane and reject an under-resolved bulge")