Luce packages
LuceLuce BaseLuciaOS

dymokomi/luce-cad

Source of release 0.9.4

0.9.4 / src / layout / counts.lucb

## Resolve compatible row counts before assigning sample phases. Unioning a
## 32-row grid with a 33-row grid creates 64 uneven rows; agreeing on 33 first
## produces one evenly distributed family instead.

## Monotone count propagation only across admitted flow seams. Hard boundaries
## keep independent face counts; shared boundary corners are conformed later.
pub func equalize_counts(edges: const Curve[], faces: const BrepFace[], sides: const PatchSides[], metrics: const ArcMetric[], plans: GridLayout[], baseline: usize[]) -> !:
    let shared = try new usize[edges.length] --- in memory.heap
    defer free(shared) in memory.heap
    let requested = try new usize[edges.length] --- in memory.heap
    defer free(requested) in memory.heap
    for pass in 0..<32:
        for edge in 0..<shared.length: shared[edge] = baseline[edge]
        for face in 0..<faces.length:
            for use in 0..<faces[face].uses.length:
                let edge = edge_index(faces[face].uses[use])
                let count = plans[face].rows[use].count - 1
                if count > shared[edge]: shared[edge] = count
        var changed = false
        for at in 0..<faces.length:
            let face = faces[at]
            let plan = plans[at]
            for use in 0..<face.uses.length:
                let edge = edge_index(face.uses[use])
                let own = plan.rows[use].count - 1
                requested[edge] = shared[edge] if plan.flow[use] else own
            if sides[at].valid and not plan.cut_first:
                for pair in 0..<(usize)2:
                    let a = side_count(face, sides[at], pair, requested)
                    let b = side_count(face, sides[at], pair + 2, requested)
                    if a == b or a > 512 or b > 512: continue
                    raise_side(face, sides[at], pair if a < b else pair + 2, requested, metrics, b if a < b else a)
            for use in 0..<face.uses.length:
                let count = requested[edge_index(face.uses[use])]
                let row = &plan.rows[use]
                if count + 1 == row.count: continue
                row.count = 0
                for step in 0..<count + 1: _ = try row.insert(metrics[edge_index(face.uses[use])].station((f64)step / (f64)count), 1e-12)
                changed = true
        if not changed: break
    # Counts stay at least as high as the independent curvature requirements.
    # The accepted parameter/arc distribution owns the eventual sample phase;
    # no original CAD vertex or trim is relocated.
    for face in 0..<faces.length:
        for use in 0..<faces[face].uses.length:
            let edge = edge_index(faces[face].uses[use])
            let count = plans[face].rows[use].count - 1
            if count > baseline[edge]: baseline[edge] = count