Luce packages
LuceLuce BaseLuciaOS

dymokomi/luce-cad

Source of release 0.9.5

0.9.5 / src / layout / patch_sides.lucb

## Recognize four logical UV sides even when STEP splits a side into many edges.

pub struct PatchSides:
    pub var starts: usize[4] = [0, 0, 0, 0]
    pub var lengths: usize[4] = [0, 0, 0, 0]
    pub var valid: bool = false

## Only single-loop, nonsingular four-corner domains qualify for mapped grids.
pub func patch_sides(face: BrepFace, edges: const Curve[]) -> PatchSides!:
    var result = PatchSides()
    if face.sizes.length != 1 or face.uses.length < 4 or face.uses.length > 128: return result
    if face.uses.length == 4:
        for side in 0..<(usize)4:
            result.starts[side] = side
            result.lengths[side] = 1
        result.valid = true
        return result
    let incoming = try new Vector3[face.uses.length] --- in memory.heap
    defer free(incoming) in memory.heap
    let outgoing = try new Vector3[face.uses.length] --- in memory.heap
    defer free(outgoing) in memory.heap
    # The turn at each corner in space (a chart's directions change with
    # the part's size: a cylinder's is angle by height).
    for at in 0..<face.uses.length:
        let use = face.uses[at]
        let edge = edges[edge_index(use)]
        var ends = [Vector3(), Vector3(), Vector3(), Vector3()]
        let fractions = [0.0, 0.001, 0.999, 1.0]
        for i in 0..<(usize)4: ends[i] = try edge.at(fractions[i] if use > 0 else 1.0 - fractions[i])
        outgoing[at] = ends[1].subtract(ends[0])
        incoming[at] = ends[3].subtract(ends[2])
    var corners: usize = 0
    for at in 0..<face.uses.length:
        let a = incoming[(at + face.uses.length - 1) % face.uses.length]
        let b = outgoing[at]
        if not (a.length() > 0.0) or not (b.length() > 0.0): return result
        if a.dot(b) < 0.99 * a.length() * b.length():
            if corners == 4: return result
            result.starts[corners] = at
            corners += 1
    if corners != 4: return result
    for side in 0..<(usize)4:
        result.lengths[side] = (result.starts[(side + 1) % 4] + face.uses.length - result.starts[side]) % face.uses.length
    result.valid = true
    return result

## Sum the independently owned edge intervals composing one logical side.
pub func side_count(face: BrepFace, sides: PatchSides, side: usize, counts: const usize[]) -> usize:
    var result: usize = 0
    for at in 0..<sides.lengths[side]: result += counts[edge_index(face.uses[(sides.starts[side] + at) % face.uses.length])]
    return result