dymokomi/luce-clipboard
Source of release 0.7.0
0.7.0 / src / clipboard / macos / native.lucb
#==============================================================================================
#
# native - The macOS pasteboard clipboard backend
#
# DESCRIPTION:
# The pasteboard owns published text and images. An autorelease pool bounds native
# temporaries even when a Base caller uses the clipboard outside the application
# event loop. Images are read as PNG, else TIFF (what screenshots and most macOS
# programs publish), and written as PNG.
#
#==============================================================================================
extern func objc_getClass(name: c.str) -> void*?
extern func sel_registerName(name: c.str) -> void*
extern func objc_autoreleasePoolPush() -> void*
extern func objc_autoreleasePoolPop(pool: void*)
extern var NSPasteboardTypeString: void*
extern var NSPasteboardTypePNG: void*
extern var NSPasteboardTypeTIFF: void*
extern func msg_object as "objc_msgSend"(object: void*, selector: void*) -> void*?
extern func msg_typed as "objc_msgSend"(object: void*, selector: void*, format: void*) -> void*?
extern func msg_count as "objc_msgSend"(object: void*, selector: void*) -> i64
extern func msg_size as "objc_msgSend"(object: void*, selector: void*, encoding: u64) -> usize
extern func msg_init as "objc_msgSend"(object: void*, selector: void*, bytes: const u8*, size: usize, encoding: u64) -> void*?
extern func msg_write as "objc_msgSend"(object: void*, selector: void*, text: void*, format: void*) -> bool
extern func msg_release as "objc_msgSend"(object: void*, selector: void*)
extern func msg_bytes as "objc_msgSend"(object: void*, selector: void*) -> const u8*?
extern func msg_data as "objc_msgSend"(object: void*, selector: void*, bytes: const u8*, size: usize) -> void*?
func mac_board() -> void*!:
let native_type = objc_getClass("NSPasteboard") else error(failed, "AppKit pasteboard is unavailable")
return msg_object(native_type, sel_registerName("generalPasteboard")) else error(failed, "the clipboard is unavailable")
func mac_read() -> interop.Owned[str]!:
let pool = objc_autoreleasePoolPush()
defer objc_autoreleasePoolPop(pool)
let board = try mac_board()
let value = msg_typed(board, sel_registerName("stringForType:"), NSPasteboardTypeString) else return try interop.copy_text("")
let length = msg_size(value, sel_registerName("lengthOfBytesUsingEncoding:"), 4)
if length > text_limit:
error(failed, "clipboard text exceeds 1 MiB")
let bytes = msg_object(value, sel_registerName("UTF8String")) else error(failed, "clipboard text is not UTF-8")
return try interop.copy_text((str)u8[]((u8*)bytes, length))
func mac_write(text: str) -> !:
let pool = objc_autoreleasePoolPush()
defer objc_autoreleasePoolPop(pool)
let board = try mac_board()
let native_type = objc_getClass("NSString") else error(failed, "Foundation strings are unavailable")
let allocated = msg_object(native_type, sel_registerName("alloc")) else error(failed, "could not allocate clipboard text")
let value = msg_init(allocated, sel_registerName("initWithBytes:length:encoding:"), text.bytes.data, text.length, 4) else error(failed, "could not create clipboard text")
defer msg_release(value, sel_registerName("release"))
_ = msg_count(board, sel_registerName("clearContents"))
if not msg_write(board, sel_registerName("setString:forType:"), value, NSPasteboardTypeString):
error(failed, "could not publish clipboard text")
func mac_read_image() -> ClipboardImage?!:
let pool = objc_autoreleasePoolPush()
defer objc_autoreleasePoolPop(pool)
let board = try mac_board()
let data = msg_typed(board, sel_registerName("dataForType:"), NSPasteboardTypePNG) else msg_typed(board, sel_registerName("dataForType:"), NSPasteboardTypeTIFF) else return none
let length = (usize)msg_count(data, sel_registerName("length"))
if length == 0 or length > image_limit:
error(failed, "the clipboard image is empty or too large")
let bytes = msg_bytes(data, sel_registerName("bytes")) else error(failed, "the clipboard image cannot be read")
let encoded = try new u8[length] --- in memory.heap
memory.copy(encoded, u8[]((u8*)bytes, length), length)
var empty: u8[]
return ClipboardImage(encoded = encoded, rgba = empty, width = 0, height = 0)
func mac_write_image(png: const u8[]) -> !:
let pool = objc_autoreleasePoolPush()
defer objc_autoreleasePoolPop(pool)
let board = try mac_board()
let native_type = objc_getClass("NSData") else error(failed, "Foundation data is unavailable")
let data = msg_data(native_type, sel_registerName("dataWithBytes:length:"), png.data, png.length) else error(failed, "could not hold the clipboard image")
_ = msg_count(board, sel_registerName("clearContents"))
if not msg_write(board, sel_registerName("setData:forType:"), data, NSPasteboardTypePNG):
error(failed, "could not publish the clipboard image")