Luce packages
LuceLuce BaseLuciaOS

dymokomi/luce-crypto

Source of release 0.6.0

0.6.0 / src / secret.lucb

import memory
import os
import sha2
import secure

pub let maximum: usize = 65536

## Native owning buffer: copies borrow, never acquire a second owner. Close only
## the original owner. A supplied allocator must outlive the buffer.
pub struct Buffer:
    var data: u8[]
    var allocator: memory.Allocator?
    var disposed: bool = true

    pub func bytes() -> const u8[]!:
        if self.disposed: error(sha2.closed, "secret is closed")
        return self.data

    pub func writable() -> u8[]!:
        if self.disposed: error(sha2.closed, "secret is closed")
        return self.data

    pub func close():
        if self.disposed: return
        secure.wipe(self.data)
        let selected = self.allocator else memory.heap
        if self.data.length > 0: free(self.data) in selected
        self = Buffer()

pub func create(count: usize, allocator: memory.Allocator? = none) -> Buffer!:
    if count > maximum: error(sha2.invalid, "secret buffer exceeds 65536 bytes")
    let selected = allocator else memory.heap
    var result = Buffer(allocator = selected, disposed = false)
    if count > 0:
        result.data = try new u8[count] --- in selected
        secure.wipe(result.data)
    return result

pub func from_bytes(data: const u8[], allocator: memory.Allocator? = none) -> Buffer!:
    var result = try create(data.length, allocator)
    for i in 0..<data.length: result.data[i] = data[i]
    return result

## Injection is for native embedders/tests only. The Luce API always uses the OS.
pub func random(count: usize, source: func(u8[]) -> unit! = os.random_bytes,
    allocator: memory.Allocator? = none) -> Buffer!:
    var result = try create(count, allocator)
    errdefer result.close()
    try source(result.data)
    return result