Luce packages
LuceLuce BaseLuciaOS

dymokomi/luce-db

Source of release 0.5.1

0.5.1 / tests / tls.lucb

## TLS listen/connect over prism.Store.
from luce_std import files
import thread
import interop
from luce_db import db
from luce_prism import prism

var g_port: @u64
var g_ready: @u64
var g_qx: u8[32]
var g_qy: u8[32]
var g_path: str
var g_stop: @u64

func owner_main(raw: void*?):
    _ = raw
    let database = db.Database.open(g_path, "secret") catch failure:
        return
    defer database.release()
    let port = database.value().listen_tls("localhost", 0) catch failure:
        return
    let x = database.value().tls_issuer_x() catch failure:
        return
    let y = database.value().tls_issuer_y() catch failure:
        return
    for i in 0..<32:
        g_qx[i] = x[i]
        g_qy[i] = y[i]
    g_port.store((u64)port, .release)
    g_ready.store(1, .release)
    while g_stop.load(.acquire) == 0:
        thread.sleep(1)

func stop_owner(worker: thread.Handle):
    g_stop.store(1, .release)
    worker.join() catch failure: trap(failure.message)

pub func main(arguments: str[]) -> i32!:
    assert(arguments.length == 2)
    g_path = arguments[1]
    g_ready.store(0, .relaxed)
    g_stop.store(0, .relaxed)
    let worker = try thread.spawn(owner_main, none, name = "db-tls")
    defer stop_owner(worker)
    var i: usize = 0
    while g_ready.load(.acquire) == 0 and i < 400:
        thread.sleep(10)
        i += 1
    assert(g_ready.load(.acquire) == 1)
    let port = (u16)g_port.load(.acquire)
    let client = try db.Database.connect_tls("localhost", port, "secret", g_qx, g_qy)
    defer client.release()
    let tx = try client.value().begin()
    defer tx.release()
    try tx.value().add("/notes", "file")
    let text = try prism.Value.text("tls")
    defer text.release()
    try tx.value().set("/notes", "text", text)
    _ = try tx.value().commit()
    tx.value().close()
    let snap = try client.value().snapshot()
    defer snap.release()
    let got = try snap.value().get("/notes", "text")
    defer got.release()
    assert(try got.value().text_at() == "tls")
    print("PASS luce-db TLS listen/connect")
    return 0