Luce packages
LuceLuce BaseLuciaOS

dymokomi/luce-dialogs

Source of release 0.6.1

0.6.1 / src / dialogs / macos / native.lucb

#==============================================================================================
#
#   native - NSOpenPanel and NSSavePanel
#
#   DESCRIPTION:
#       AppKit's panels, run modally. An open panel chooses files, or folders only. Its chosen
#       URL's path is copied out before the pool drains.
#
#       Making a panel is slow: AppKit's first NSOpenPanel takes about 260 ms on an M4 Max,
#       later ones about 100 ms, while showing a panel kept from before takes about 20 ms. So
#       each kind of panel is made once, kept for the process and set up afresh on every use,
#       and `mac_prepare` makes the open panel ahead of time, when the app is idle.
#
#==============================================================================================

## The panels made so far, kept (retained) for the process: open, save.
var mac_open_panel: void*? = none
var mac_save_panel: void*? = none

extern func objc_getClass(name: c.str) -> void*?
extern func sel_registerName(name: c.str) -> void*
extern func objc_autoreleasePoolPush() -> void*
extern func objc_autoreleasePoolPop(pool: void*)
## Naming an AppKit symbol links AppKit for programs that only open dialogs.
extern var NSApplicationDidFinishLaunchingNotification: void*
extern func msg_object as "objc_msgSend"(object: void*, selector: void*) -> void*?
extern func msg_set_object as "objc_msgSend"(object: void*, selector: void*, value: void*?)
extern func msg_set_bool as "objc_msgSend"(object: void*, selector: void*, value: bool)
extern func msg_int as "objc_msgSend"(object: void*, selector: void*) -> i64
extern func msg_size as "objc_msgSend"(object: void*, selector: void*, encoding: u64) -> usize
extern func msg_init as "objc_msgSend"(object: void*, selector: void*, bytes: const u8*, size: usize, encoding: u64) -> void*?
extern func msg_release as "objc_msgSend"(object: void*, selector: void*)
extern func msg_at as "objc_msgSend"(object: void*, selector: void*, index: u64) -> void*?

func mac_text(text: str) -> void*!:
    let native_type = objc_getClass("NSString") else error(failed, "Foundation strings are unavailable")
    let allocated = msg_object(native_type, sel_registerName("alloc")) else error(failed, "could not allocate dialog text")
    return msg_init(allocated, sel_registerName("initWithBytes:length:encoding:"), text.bytes.data, text.length, 4) else error(failed, "could not create dialog text")

## `path`, an NSString, as UTF-8 bytes borrowed until the pool drains.
func mac_path(path: void*) -> str!:
    let length = msg_size(path, sel_registerName("lengthOfBytesUsingEncoding:"), 4)
    let bytes = msg_object(path, sel_registerName("UTF8String")) else error(failed, "the chosen path is not UTF-8")
    return (str)u8[]((u8*)bytes, length)

## The kept open (or save) panel, made and retained on first use.
func mac_panel(save: bool) -> void*!:
    if let kept = (mac_save_panel if save else mac_open_panel):
        return kept
    _ = NSApplicationDidFinishLaunchingNotification
    let native_type = objc_getClass("NSSavePanel" if save else "NSOpenPanel") else error(failed, "AppKit panels are unavailable")
    let made = msg_object(native_type, sel_registerName("savePanel" if save else "openPanel")) else error(failed, "could not create the file panel")
    # Autoreleased: retained, it outlives the pool it was made in.
    _ = msg_object(made, sel_registerName("retain"))
    if save:
        mac_save_panel = made
    else:
        mac_open_panel = made
    return made

## Make the open panel now, so the first open dialog shows at once.
func mac_prepare() -> !:
    let pool = objc_autoreleasePoolPush()
    defer objc_autoreleasePoolPop(pool)
    _ = try mac_panel(false)

func mac_choose(message: str, name: str, save: bool, multiple: bool, folders: bool = false) -> interop.Owned[str]?!:
    let pool = objc_autoreleasePoolPush()
    defer objc_autoreleasePoolPop(pool)
    let panel = try mac_panel(save)
    let caption = try mac_text(message)
    defer msg_release(caption, sel_registerName("release"))
    msg_set_object(panel, sel_registerName("setMessage:"), caption)
    if save:
        let suggested = try mac_text(name)
        defer msg_release(suggested, sel_registerName("release"))
        msg_set_object(panel, sel_registerName("setNameFieldStringValue:"), suggested)
    else:
        msg_set_bool(panel, sel_registerName("setCanChooseFiles:"), not folders)
        msg_set_bool(panel, sel_registerName("setCanChooseDirectories:"), folders)
        msg_set_bool(panel, sel_registerName("setAllowsMultipleSelection:"), multiple)
    # NSModalResponseOK is 1.
    if msg_int(panel, sel_registerName("runModal")) != 1:
        return none
    if multiple:
        # Every chosen file, one to a line.
        let urls = msg_object(panel, sel_registerName("URLs")) else return none
        let count = msg_int(urls, sel_registerName("count"))
        var joined: collections.Buffer
        defer joined.destroy()
        var index: i64 = 0
        while index < count:
            let url = msg_at(urls, sel_registerName("objectAtIndex:"), (u64)index) else error(failed, "a chosen file went missing")
            let path = msg_object(url, sel_registerName("path")) else error(failed, "the chosen file has no path")
            if index > 0:
                try joined.put_text("\n")
            try joined.put_text(try mac_path(path))
            index += 1
        return try interop.copy_text(joined.text()) if count > 0 else none
    let url = msg_object(panel, sel_registerName("URL")) else return none
    let path = msg_object(url, sel_registerName("path")) else error(failed, "the chosen file has no path")
    return try interop.copy_text(try mac_path(path))