Luce packages
LuceLuce BaseLuciaOS

dymokomi/luce-pkg

Source of release 0.6.1

0.6.1 / src / pkg_tests.lucb

import pkg
import strings

func rejected(text: str) -> bool:
    _ = pkg.parse_version(text) catch failure:
        assert(failure.code == pkg.invalid)
        return true
    return false

pub func main(arguments: str[]) -> i32!:
    _ = arguments
    let v = try pkg.parse_version("1.2.3")
    assert(v.major == 1 and v.minor == 2 and v.patch == 3)
    let largest = try pkg.parse_version("18446744073709551615.18446744073709551615.18446744073709551615")
    assert(largest.major == 18446744073709551615 and largest.minor == largest.major and largest.patch == largest.major)
    for oversized in ["18446744073709551616", "30000000000000000000", "36893488147419103231", "99999999999999999999999999"]:
        for component in 0..<3:
            var buffer: u8[128]
            let text = try strings.format(buffer, f"{oversized}.0.0" if component == 0 else (f"0.{oversized}.0" if component == 1 else f"0.0.{oversized}"))
            assert(rejected(text))
    for bad in ["01.2.3", "1.2.3-beta", "1.2", "1.2.3.4", "", "a.b.c", "1..3", " 1.2.3"]:
        assert(rejected(bad))
    var digest: u8[32]
    assert(try pkg.source_digest(b"abc", digest) == 32)
    assert(digest[0] == 0xba and digest[1] == 0x78 and digest[31] == 0xad)
    var short: u8[16]
    var failed = false
    _ = pkg.source_digest(b"abc", short) catch failure:
        failed = true
        recover 0
    assert(failed)
    print("PASS numeric versions and SHA-256 source digests")
    return 0