Luce packages
LuceLuce BaseLuciaOS

dymokomi/luce-ply

Source of release 0.1.0

0.1.0 / tests / ply / build.lucb

## Byte builders for the fixtures: header text and values in either byte order.
from luce_geocore.core.growing import Growing

pub struct Bytes:
    pub var data: Growing[u8]
    pub var big: bool = false

    pub func text(value: str) -> !:
        for byte in value.bytes: try self.data.push(byte)

    pub func put_u8(value: u8) -> !:
        try self.data.push(value)

    pub func put_u16(value: u16) -> !:
        if self.big:
            try self.data.push((u8)(value >> 8))
            try self.data.push((u8)value)
        else:
            try self.data.push((u8)value)
            try self.data.push((u8)(value >> 8))

    pub func put_u32(value: u32) -> !:
        for at in 0..<(u32)4:
            let shift = (3 - at) * 8 if self.big else at * 8
            try self.data.push((u8)(value >> shift))

    pub func put_i32(value: i32) -> !:
        try self.put_u32((u32)value)

    pub func put_f32(value: f32) -> !:
        try self.put_u32(value.bits())

    pub func put_f64(value: f64) -> !:
        let bits = value.bits()
        for at in 0..<(u64)8:
            let shift = (7 - at) * 8 if self.big else at * 8
            try self.data.push((u8)(bits >> shift))

    pub func view() -> const u8[]:
        return self.data.view()

    pub func close():
        self.data.close()