Luce packages
LuceLuce BaseLuciaOS

dymokomi/luce-prism

Source of release 0.6.0

0.6.0 / tests / bench_store.lucb

## How a durable Store holds up as a mail store: 50k messages in one folder, with the
## eight fields a message list shows. Not part of the gate; run it by hand:
##     luce-base build tests/bench_store.lucb --native --opt 2 -o build/bench
##     build/bench DIR/mail.db write    # insert in 1000-message commits, bake, close
##     build/bench DIR/mail.db open     # reopen five times
##     build/bench DIR/mail.db query    # newest 100 by date, five times
from luce_prism import prism
import interop
import time
import strings

let messages: usize = 50000

func since(start: u64) -> f64:
    return (f64)(time.now() - start) / 1000000.0

func put_integer(session: interop.Reference[prism.Session], path: str, name: str, value: i64) -> !:
    let v = try prism.Value.integer(value)
    defer v.release()
    try session.value().set(path, name, v)

func put_text(session: interop.Reference[prism.Session], path: str, name: str, value: str) -> !:
    let v = try prism.Value.text(value)
    defer v.release()
    try session.value().set(path, name, v)

func write(path: str) -> !:
    var start = time.now()
    let store = try prism.Store.open(path)
    defer store.release()
    try store.value().mount("acct")
    var uid: usize = 0
    while uid < messages:
        let tx = try store.value().begin_identity("acct")
        defer tx.release()
        if uid == 0:
            try tx.value().add("/inbox", "folder")
        for _ in 0..<1000:
            uid += 1
            var name: u8[64]
            let element = try strings.format(name, f"/inbox/m{uid}")
            try tx.value().add(element, "message")
            try put_integer(tx, element, "uid", (i64)uid)
            try put_integer(tx, element, "flags", (i64)(uid % 4))
            try put_integer(tx, element, "date", 1790000000 + (i64)uid * 37 % 100000)
            try put_integer(tx, element, "size", 2048 + (i64)uid % 9000)
            var sender: u8[64]
            try put_text(tx, element, "sender", try strings.format(sender, f"Robot {uid % 97} <robot{uid % 97}@example.net>"))
            var subject: u8[96]
            try put_text(tx, element, "subject", try strings.format(subject, f"Report #{uid}: nightly build of luce {uid % 13}"))
            var id: u8[96]
            try put_text(tx, element, "message_id", try strings.format(id, f"<{uid}.nightly@example.net>"))
            try put_text(tx, element, "preview", "Build finished. Nothing to see here; all tests passed on every platform and the artifacts are uploaded.")
        _ = try tx.value().commit()
    print(f"insert {messages} in commits of 1000: {since(start)} ms")
    start = time.now()
    _ = try store.value().bake_identity("acct")
    print(f"bake: {since(start)} ms")
    start = time.now()
    store.value().close()
    print(f"close: {since(start)} ms")

func reopen(path: str) -> !:
    for _ in 0..<5:
        let start = time.now()
        let store = try prism.Store.open(path)
        print(f"reopen: {since(start)} ms")
        store.value().close()
        store.release()

func newest(path: str) -> !:
    let store = try prism.Store.open(path)
    defer store.release()
    let snap = try store.value().snapshot_identity("acct")
    defer snap.release()
    for _ in 0..<5:
        let start = time.now()
        var query = try snap.value().query("/inbox/*")
        defer query.close()
        let ordered = try query.order_by("date")
        defer ordered.release()
        let latest = try ordered.value().reverse()
        defer latest.release()
        let page = try latest.value().limit(100)
        defer page.release()
        let rows = try page.value().select()
        defer rows.release()
        print(f"newest {rows.value().count()} by date: {since(start)} ms")

pub func main(arguments: str[]) -> i32!:
    if arguments.length != 3:
        print("usage: bench_store DATABASE write|open|query")
        return 2
    if arguments[2] == "write":
        try write(arguments[1])
    elif arguments[2] == "open":
        try reopen(arguments[1])
    else:
        try newest(arguments[1])
    return 0