Luce packages
LuceLuce BaseLuciaOS

dymokomi/luce-prism

Source of release 0.6.1

0.6.1 / src / query / field_index.lucb

## Snapshot value index. Exact scalar keys keep large integer identifiers distinct.
import interop
import query.scalars
from collections.index import Index
from query.results import Selection, own_selection
from document import Document, assemble_element, walk_document
from model import Element, close_elements
from storage import List
from value import Value
from animation import resolve_property

pub struct FieldIndex:
    var rows: List[Element]
    var index: Index

    pub func init(doc: interop.Reference[Document], field: str) -> !:
        self.rows = List[Element]()
        self.index = Index()
        errdefer self.close()
        let view = try doc.get()
        if view.is_layered():
            var paths = try walk_document(view)
            defer paths.close()
            for path in paths.span():
                var element = try assemble_element(view, path)
                defer element.close()
                try self.index_row(&element, field)
        else:
            for element in view.view_data().elements.span():
                try self.index_row(&element, field)

    func index_row(element: const Element*, field: str) -> !:
        let position = element.property(field) else return
        var value = try resolve_property(&element.properties.items[position], 0.0)
        defer value.close()
        if let result = try scalars.key(&value):
            var key = result
            defer key.close()
            var owned = try element.copy()
            errdefer owned.close()
            _ = try self.index.add(key.view(), self.rows.count)
            try self.rows.push(owned)
            owned = Element()

    pub func key_count() -> usize:
        return self.index.buckets.count

    pub func equals(value: interop.Reference[Value]) -> interop.Reference[Selection]!:
        var selection = Selection()
        errdefer selection.close()
        if let result = try scalars.key((try value.get()).view_data()):
            var key = result
            defer key.close()
            if let position = self.index.find(key.view()):
                for row in self.index.buckets.items[position].rows.span():
                    try selection.append(&self.rows.items[row])
        let owned = selection
        selection = Selection()
        return try own_selection(owned)

    pub func contains(value: interop.Reference[Value]) -> bool!:
        if let result = try scalars.key((try value.get()).view_data()):
            var key = result
            defer key.close()
            return self.index.find(key.view()) != none
        return false

    pub func close():
        close_elements(&self.rows)
        self.index.close()

pub let field_index_type = interop.Type[FieldIndex]("Prism field index", FieldIndex.close, closeable = true)