Luce packages
LuceLuce BaseLuciaOS

dymokomi/luce-server

Source of release 0.5.1

0.5.1 / src / internal / responses.lucb

## Response storage is assembled by one application owner, then committed under
## the server lock. Network threads observe immutable bytes after commitment.

import io
import internal.dates
from internal.model import Exchange
import internal.response_data
import internal.storage
from luce_std import net
import time

pub func send(destination: io.Writer, request: Exchange*, keep_alive: bool) -> !:
    var fields: net.HttpField[100]
    var date_buffer: u8[29]
    fields[0] = net.HttpField(name = "Date", value = try dates.format_http(time.unix(), date_buffer))
    var count: usize = 1
    if request.http().reply.content_type.used > 0:
        fields[count] = net.HttpField(name = "Content-Type", value = (str)request.http().reply.content_type.view())
        count += 1
    let extra = (str)request.http().reply.headers.view()
    var at: usize = 0
    while at < extra.length:
        let start = at
        while at < extra.length and extra.bytes[at] != ':':
            at += 1
        let name = (str)extra.bytes[start..<at]
        at += 2
        let value_start = at
        while at + 1 < extra.length and extra.bytes[at] != '\r':
            at += 1
        if count == 98:
            error(storage.limit, "too many response fields")
        fields[count] = net.HttpField(name = name, value = (str)extra.bytes[value_start..<at])
        count += 1
        at += 2
    let length = request.http().reply.file_length if request.http().reply.is_file else (u64)request.http().reply.bytes.used
    let no_body = request.http().reply.status == 204 or request.http().reply.status == 304
    var head_buffer: u8[16384]
    let encoded = try net.http_encode_head(head_buffer, net.HttpHead(method = request.http().head.method, version = request.http().head.version,
                                                                     status = request.http().reply.status, fields = fields[..<count], body_kind = net.HttpBodyKind.empty if no_body else net.HttpBodyKind.fixed,
                                                                     body_length = length, keep_alive = keep_alive))
    try io.write_all(destination, encoded)
    if request.http().head.method == "HEAD" or no_body:
        return
    var writer = try net.HttpBodyWriter.over(destination, net.HttpBodyKind.fixed, length)
    if request.http().reply.is_file:
        var block: u8[32768]
        var remaining = length
        while remaining > 0:
            let amount = (usize)remaining if remaining < (u64)block.length else block.length
            let read = try request.http().reply.file.read(block[..<amount])
            if read == 0:
                error(io.unexpected_eof, "response file was truncated during transfer")
            _ = try writer.write(block[..<read])
            remaining -= (u64)read
    else:
        _ = try writer.write(request.http().reply.bytes.view())
    try writer.finish()

pub func field(request: Exchange*, name: str, value: str) -> !:
    try response_data.field(&request.http().reply, name, value)

pub func content(request: Exchange*, status: i64, content_type: str, data: const u8[]) -> !:
    try response_data.content(&request.http().reply, status, content_type, data)