Luce packages
LuceLuce BaseLuciaOS

dymokomi/luce-std

Source of release 0.7.0

0.7.0 / tests / unit / paths_test.lucb

## The `paths` module against its archive: lexical splitting and joining.
import paths
import platform

test "paths split into their parts and join":
    # a rooted path is absolute on POSIX; Windows asks for a drive or a UNC share as well
    assert(paths.is_absolute("C:/usr/lib" if platform.windows else "/usr/lib") and not paths.is_absolute("usr/lib"))
    assert(paths.directory("/usr/lib/x.a") == "/usr/lib" and paths.directory("x.a") == ".")
    assert(paths.base("/usr/lib/x.a") == "x.a" and paths.base("x.a") == "x.a")
    assert(paths.extension("x.tar.gz") == ".gz" and paths.extension("x") == "")
    assert(paths.stem("/usr/lib/x.a") == "x" and paths.stem("noext") == "noext")
    let joined = try paths.join("/usr", "lib")
    defer joined.release()
    assert(joined.value == "/usr/lib")
    let absolute_wins = try paths.join("/usr", "C:/etc" if platform.windows else "/etc")
    defer absolute_wins.release()
    assert(absolute_wins.value == ("C:/etc" if platform.windows else "/etc"))
    let normal = try paths.normalize("a/./b/../c")
    defer normal.release()
    assert(normal.value == "a/c")

test "join_into writes a path with no allocation":
    var buffer: u8[64] = ---
    assert(paths.join_into(buffer[0..], "/usr", "lib") == "/usr/lib")
    assert(paths.join_into(buffer[0..], "/usr/", "lib") == "/usr/lib")   # no doubled separator
    assert(paths.join_into(buffer[0..], "", "lib") == "lib")             # empty left is the right path
    let root = "C:/etc" if platform.windows else "/etc"
    assert(paths.join_into(buffer[0..], "/usr", root) == root)           # an absolute right wins
    let written = paths.join_into(buffer[0..], "dir", "file")
    assert(buffer[written.length] == 0)                                  # NUL-terminated, usable as c.str
    var tiny: u8[4] = ---
    assert(paths.join_into(tiny[0..], "dir", "file").length == 0)        # "" when it does not fit