Luce packages
LuceLuce BaseLuciaOS

dymokomi/luce-std

Source of release 0.7.2

0.7.2 / tests / file_mutations / check.lucb

import c
import files
import interop
import io
import strings

pub func main(arguments: c.str[]) -> i32!:
    let directory = arguments[1]
    let original = arguments[2]
    let hard = arguments[3]
    let link = arguments[4]
    let dangling = arguments[5]
    let renamed = arguments[6]
    let link_alias = arguments[7]
    try files.create_directory(directory)
    var rejected = false
    files.create_directory(directory) catch failure:
        assert(failure.code == files.already_exists)
        rejected = true
    assert(rejected)
    try files.write(original, "original".bytes)
    var held = try files.File.open(original)
    defer held.destroy()
    try files.create_hard_link(original, hard)
    try files.create_symlink("data", link)
    try files.create_hard_link(link, link_alias)
    let target = try files.read_symlink(link_alias, 4)
    defer target.release()
    assert(target.value == "data", "hard-link creation followed the source symlink")
    assert(try files.exists_checked(link))
    try files.create_symlink("missing", dangling)
    assert(not (try files.exists_checked(dangling)))
    rejected = false
    files.create_symlink("new-target", dangling) catch failure:
        assert(failure.code == files.already_exists)
        rejected = true
    assert(rejected)
    rejected = false
    let excess = files.read_symlink(dangling, 3) catch failure:
        assert(failure.code == files.too_large)
        rejected = true
        recover interop.Owned[str]("")
    excess.release()
    assert(rejected)
    let missing = try files.read_symlink(dangling, 7)
    defer missing.release()
    assert(missing.value == "missing")
    var published = false
    try files.write_atomic(dangling, "atomic".bytes, published = &published)
    assert(published)
    let published_contents_file = try files.read(dangling)
    defer published_contents_file.release()
    let published_contents = published_contents_file.value
    assert((str)published_contents == "atomic")
    try files.write_atomic(dangling, "".bytes)
    let empty_contents_file = try files.read(dangling)
    defer empty_contents_file.release()
    let empty_contents = empty_contents_file.value
    assert(empty_contents.length == 0)
    rejected = false
    files.remove_directory(directory) catch failure:
        assert(failure.code == files.not_empty or failure.code == files.already_exists)
        rejected = true
    assert(rejected)
    rejected = false
    files.remove_directory(link) catch failure:
        assert(failure.code == files.not_directory)
        rejected = true
    assert(rejected)
    try files.write(renamed, "replaced".bytes)
    try files.rename(original, renamed)
    assert(not (try files.exists_checked(original)))
    assert(not (try files.exists_checked(link)))
    let contents_file = try files.read(renamed)
    defer contents_file.release()
    let contents = contents_file.value
    assert((str)contents == "original")
    try files.remove_file(hard)
    try files.remove_file(renamed)
    var bytes: u8[8]
    try io.read_exact(&held, bytes)
    assert((str)bytes == "original", "unlink invalidated an open handle")
    try held.close()
    try files.remove_file(link)
    try files.remove_file(link_alias)
    try files.remove_file(dangling)
    rejected = false
    files.remove_file(original) catch failure:
        assert(failure.code == files.missing)
        rejected = true
    assert(rejected)
    try files.remove_directory(directory)
    assert(not (try files.exists_checked(directory)))
    print("ok file mutations and link semantics")
    return 0