Luce packages
LuceLuce BaseLuciaOS

dymokomi/luce-ui

Source of release 0.19.0

0.19.0 / src / widgets / viewport.lucb

## The Viewport widget: an application-drawn area inside the widget tree.
from luce_gpu import gpu
import interop
from luce_std import math
import ownership
import layout
import result
from layout import Widget, Layout, Size, Constraints, Event
from painter import Painter

## A flexible area, at least `width` by `height` points, that the application
## draws itself: each frame it hands its clipped render target to the
## `on_render` callbacks. It takes no input.
pub struct Viewport: Widget:
    let box: interop.Reference[Layout]
    let rendering: interop.Signal[interop.View[gpu.RenderTarget]]

    pub func init(width: f64 = 320.0, height: f64 = 240.0) -> !:
        let box = try layout.make_layout()
        errdefer box.release()
        try box.value().set_limits(Size(width, height), Size(16384.0, 16384.0))
        try box.value().set_flex()
        let signal = try interop.Signal[interop.View[gpu.RenderTarget]]()
        self.rendering = signal
        self.box = box

    pub func layout() -> interop.Reference[Layout]:
        return self.box.clone()

    ## Called every time the viewport draws, with a target local to its bounds.
    pub func on_render(callback: interop.Callback[interop.View[gpu.RenderTarget], unit]) -> interop.Reference[interop.Connection]!:
        return try self.rendering.connect(callback)

    pub func measure(available: Constraints) -> interop.Outcome[Size]:
        return result.success[Size](Size())

    pub func draw(target: interop.View[gpu.RenderTarget]) -> interop.Outcome[unit]:
        return self.rendering.emit(target)

    pub func event(event: Event) -> interop.Outcome[unit]:
        return result.success[unit](())

    pub func close():
        self.rendering.close()
        self.rendering.release()
        self.box.release()

    func trace(visit: func(ownership.Object*, void*) -> unit, context: void*):
        self.box.trace(visit, context)
        self.rendering.trace(visit, context)

pub let viewport_type: interop.Type[Viewport] = interop.Type[Viewport]("Viewport", Viewport.close, Viewport.trace, closeable = true, main_thread = true)