Luce packages
LuceLuce BaseLuciaOS

dymokomi/luce-ui

Source of release 0.19.1

0.19.1 / src / widgets / rule.lucb

## The Rule widget: a one-point divider line.
from luce_gpu import gpu
import interop
import ownership
import layout
import result
from layout import Widget, Layout, Size, Constraints, Event
from painter import Painter

## A one-point rule across its row (or down its column when `vertical`):
## `border` between property rows, or the backdrop for a structural edge when
## `structural`, such as the edge between a tool rail and a canvas.
pub struct Rule: Widget:
    let box: interop.Reference[Layout]
    var structural: bool
    var vertical: bool

    pub func init(structural: bool = false, vertical: bool = false) -> !:
        let box = try layout.make_layout()
        errdefer box.release()
        if vertical:
            try box.value().set_shrink(horizontal = 0.0)
            try box.value().set_flex(horizontal = 0.0)
        else:
            try box.value().set_shrink(vertical = 0.0)
        self.box = box
        self.structural = structural
        self.vertical = vertical

    pub func layout() -> interop.Reference[Layout]:
        return self.box.clone()

    pub func measure(available: Constraints) -> interop.Outcome[Size]:
        return result.success[Size](Size(1.0, 0.0) if self.vertical else Size(0.0, 1.0))

    pub func draw(target: interop.View[gpu.RenderTarget]) -> interop.Outcome[unit]:
        self.paint(target) catch failure:
            return result.failure[unit](failure.code, failure.message)
        return result.success[unit](())

    func paint(target: interop.View[gpu.RenderTarget]) -> !:
        var painter = try Painter(target)
        defer painter.close()
        let size = try target.get().size()
        let theme = self.box.value().theme()
        try painter.rectangle(gpu.Rect(width = size.width, height = size.height), theme.background if self.structural else theme.border)

    pub func event(event: Event) -> interop.Outcome[unit]:
        return result.success[unit](())

    pub func close():
        self.box.release()

    func trace(visit: func(ownership.Object*, void*) -> unit, context: void*):
        self.box.trace(visit, context)

pub let rule_type: interop.Type[Rule] = interop.Type[Rule]("Rule", Rule.close, Rule.trace, closeable = true, main_thread = true)