Luce packages
LuceLuce BaseLuciaOS

dymokomi/luce-ui

Source of release 0.19.3

0.19.3 / src / widgets / icon.lucb

## The Icon widget.
from luce_gpu import gpu
import interop
import ownership
import icons
import layout
import result
from icons import IconKind
from layout import Widget, Layout, Size, Constraints, Event
from painter import Painter
from font import Font, selected_font

## One built-in icon (an IconKind), drawn in the theme's foreground as a square
## of the font's height, centered in a box one line tall.
pub struct Icon: Widget:
    let box: interop.Reference[Layout]
    let font: interop.Reference[Font]
    var kind: IconKind

    pub func init(kind: IconKind, font: interop.Reference[Font]? = none) -> !:
        let selected = try selected_font(font)
        errdefer selected.release()
        self.box = try layout.make_layout()
        self.font = selected
        self.kind = kind

    pub func layout() -> interop.Reference[Layout]:
        return self.box.clone()

    pub func set_kind(kind: IconKind):
        self.kind = kind
        self.box.value().invalidate()

    pub func measure(available: Constraints) -> interop.Outcome[Size]:
        return result.success[Size](Size(self.font.value().height(), self.font.value().line_height()))

    pub func draw(target: interop.View[gpu.RenderTarget]) -> interop.Outcome[unit]:
        self.paint(target) catch failure:
            return result.failure[unit](failure.code, failure.message)
        return result.success[unit](())

    func paint(target: interop.View[gpu.RenderTarget]) -> !:
        var painter = try Painter(target)
        defer painter.close()
        let size = try target.get().size()
        let extent = self.font.value().height()
        try icons.draw(&painter, self.kind, gpu.Rect((size.width - extent) * 0.5, (size.height - extent) * 0.5, extent, extent), self.box.value().theme().foreground)

    pub func event(event: Event) -> interop.Outcome[unit]:
        return result.success[unit](())

    pub func close():
        self.font.release()
        self.box.release()

    func trace(visit: func(ownership.Object*, void*) -> unit, context: void*):
        self.font.trace(visit, context)
        self.box.trace(visit, context)

pub let icon_type: interop.Type[Icon] = interop.Type[Icon]("Icon", Icon.close, Icon.trace, closeable = true, main_thread = true)