Luce packages
LuceLuce BaseLuciaOS

dymokomi/luce-usd

Source of release 0.9.2

0.9.2 / tests / api / geometry_tests.luc

## Usd.load, save, convert, info and warnings as luced-3d calls them.
from luce_usd.usd import Usd
from luce_geocore.geocore import invalid, Mesh, GeometrySet
from luce_cad.solids import CadSolids
from luce_cad.cad_geometry import CadGeometry
from luce_std import paths

pub func geometry_tests(scratch: str) -> unit!:
    let loaded = Usd.load("tests/fixtures/geom/meshes.usda")
    let mesh = loaded.mesh() else error(invalid, "no mesh")
    assert(mesh.face_count() == 3)
    assert(Usd.warnings().contains("faces with fewer than 3 corners"))
    assert(loaded.detail_value("usd.time") == 1.0)
    let later = Usd.load("tests/fixtures/geom/meshes.usda", time = 2.0)
    assert((later.mesh() else error(invalid, "no mesh")).point(6).x == 2.0)
    for extension in ["usda", "usdc", "usdz"]:
        let name = paths.join(scratch, f"saved.{extension}")
        Usd.save(loaded, name)
        let again = Usd.load(name)
        assert((again.mesh() else error(invalid, "no mesh")).face_count() == 3)
    assert(Usd.serialization(paths.join(scratch, "saved.usdz")) == "usdz")
    Usd.convert(paths.join(scratch, "saved.usdc"), paths.join(scratch, "converted.usda"))
    assert(Usd.serialization(paths.join(scratch, "converted.usda")) == "usda")
    let info = Usd.info("tests/fixtures/geom/meshes.usda")
    assert(info.contains("upAxis: Z") and info.contains("type Mesh: 2") and info.contains("prims: "))
    let flat = Usd.load("tests/fixtures/geom/instancer.usda", flatten = true)
    assert((flat.mesh() else error(invalid, "no mesh")).face_count() == 7)
    let placed = Usd.load("tests/fixtures/geom/instancer.usda")
    assert(placed.instance_count() == 3)
    # Array attributes have no primvar form yet: left out with a warning.
    let counts: list[int] = []
    for at in 0..<mesh.point_count():
        counts.append(1 if at == 0 else (2 if at == 1 else 0))
    let listed = mesh.with_array_attribute("nbrs", 0, true, 1, counts, [7.0, 8.0, 9.0])
    Usd.save(GeometrySet.of_mesh(listed), paths.join(scratch, "arrays.usda"))
    assert(Usd.warnings().contains("Array attributes have no USD primvar form"))
    assert((Usd.load(paths.join(scratch, "arrays.usda")).mesh() else error(invalid, "no mesh")).face_count() == 3)
    # CAD saves as NurbsPatch prims, one per face.
    let solid = CadGeometry.of_model(CadSolids.cylinder(1.0, 2.0))
    Usd.save(solid, paths.join(scratch, "cylinder.usda"))
    assert(Usd.info(paths.join(scratch, "cylinder.usda")).contains("type NurbsPatch: 3"))
    # A spline-animated size: 2 halfway, 3 once held after its last knot.
    let halfway = Usd.load("tests/fixtures/geom/spline_size.usda", time = 5.0, subdivide = false)
    assert(largest_x(halfway.mesh() else error(invalid, "no mesh")) == 1.0)
    let held = Usd.load("tests/fixtures/geom/spline_size.usda", time = 20.0, subdivide = false)
    assert(largest_x(held.mesh() else error(invalid, "no mesh")) == 1.5)

## A composed stage: the museum's time-offset case loads through its
## references and sublayers, and flattens to a file.
pub func composed_tests(scratch: str) -> unit!:
    let loaded = Usd.load("tests/fixtures/openusd/museum/BasicAncestralReference/root.usda")
    assert(loaded.is_empty())
    Usd.flatten("tests/fixtures/openusd/museum/BasicTimeOffset/root.usda", paths.join(scratch, "flat.usda"))
    assert(Usd.info(paths.join(scratch, "flat.usda")).contains("prims: "))
    stage_option_tests()

## Variant selections and payload masks, and the composition summary the
## File node shows: the room's table top is a quad or two triangles, its
## lamp a payload of three triangles, its two chairs instances.
func stage_option_tests() -> unit!:
    let room = "tests/fixtures/geom/room.usda"
    let loaded = Usd.load(room)
    assert((loaded.mesh() else error(invalid, "no mesh")).face_count() == 4)
    assert(loaded.instance_count() == 2)
    let chosen = Usd.load(room, variants = "/Room/Table{ top = triangles }")
    assert((chosen.mesh() else error(invalid, "no mesh")).face_count() == 5)
    let bare = Usd.load(room, payloads = "-")
    assert((bare.mesh() else error(invalid, "no mesh")).face_count() == 1)
    let lamp = Usd.load(room, payloads = "/Room/Lamp*")
    assert((lamp.mesh() else error(invalid, "no mesh")).face_count() == 4)
    assert(Usd.composition(room) == "2\t7\t2\n/Room/Table\ttop\tquad\tquad|triangles\n")
    let composed = Usd.composition(room, variants = "/Room/Table{top=triangles}", payloads = "-")
    assert(composed == "1\t5\t2\n/Room/Table\ttop\ttriangles\tquad|triangles\n")

func largest_x(mesh: Mesh) -> float!:
    var most = -1000000.0
    for at in 0..<mesh.point_count():
        let x = mesh.point(at).x
        if x > most:
            most = x
    return most