Luce packages
LuceLuce BaseLuciaOS

dymokomi/luced-photo

Source of release 0.1.1

0.1.1 / tests / presets / main.lucb

## Presets round-trip through a fresh catalog: save, save again by the same name,
## rename, change what the Library shows, delete, folders (made, saved into,
## moved into, renamed, deleted), and read back after reopening. The catalog is made in the folder
## given, or in a temporary folder under build/ that is removed after. Prints PASS
## or traps.
import c
import interop
import strings
from luce_prism import prism
from luce_std import files
from luce_std import paths
import presets

func names(store: interop.Reference[prism.Store]) -> interop.Reference[presets.PresetList]!:
    return try presets.read_presets(store)

pub func main(arguments: str[]) -> i32!:
    if arguments.length > 1:
        try files.ensure_directory(arguments[1])
        try check(arguments[1])
        return 0
    try files.ensure_directory("build")
    let folder = try files.create_temporary_directory("build")
    defer folder.release()
    let terminated = try strings.copy(folder.value)
    defer strings.release(terminated)
    defer files.remove_tree((c.str)terminated) catch failure:
        _ = failure
    try check(folder.value)
    return 0

## The round trip, in `folder`.
func check(folder: str) -> !:
    let path = try paths.join(folder, "presets.prism")
    defer path.release()
    var store = try prism.Store.open(path.value)
    var list = try names(store)
    assert((try list.get()).count() == 0)
    let warm = try presets.save_preset(store, list, "Warm", "temperature=6500", presets.default_exposed)
    list.release()
    list = try names(store)
    let mono = try presets.save_preset(store, list, "mono", "bw=1", "exposure")
    list.release()
    list = try names(store)
    # The same name, in another case, replaces the name and settings, keeping the id.
    let again = try presets.save_preset(store, list, "WARM", "temperature=7000;saturation=10", "exposure|saturation")
    assert(again == warm and mono != warm)
    try presets.rename_preset(store, mono, "Black and White")
    try presets.set_exposed(store, mono, "exposure|film_grain")
    list.release()
    (try store.get()).close()
    store.release()
    store = try prism.Store.open(path.value)
    list = try names(store)
    let read = try list.get()
    assert(read.count() == 2)
    assert(read.name(0) == "Black and White" and read.settings(0) == "bw=1")
    assert(read.name(1) == "WARM" and read.settings(1) == "temperature=7000;saturation=10")
    assert(read.exposed(0) == "exposure|film_grain" and read.exposed(1) == "exposure|saturation")
    assert(read.position_of(mono) == 0 and read.position_of(999) == -1)
    try presets.delete_preset(store, warm)
    list.release()
    list = try names(store)
    assert((try list.get()).count() == 1 and (try list.get()).id(0) == mono)
    # The next preset takes a fresh id, not the deleted one's.
    let fresh = try presets.save_preset(store, list, "Fresh", "", "")
    assert(fresh != warm and fresh != mono)
    # Folders: made, a preset saved into one and one moved into the other;
    # deleting a folder leaves its presets in none.
    list.release()
    list = try names(store)
    let portraits = try presets.make_folder(store, list, "Portraits")
    list.release()
    list = try names(store)
    let night = try presets.make_folder(store, list, "Night")
    list.release()
    list = try names(store)
    let skin = try presets.save_preset(store, list, "Skin", "exposure=0.3", "exposure", portraits)
    try presets.move_preset(store, mono, night)
    list.release()
    list = try names(store)
    var known = try list.get()
    assert(known.folder_count() == 2 and known.folder_name(0) == "Night" and known.folder_name(1) == "Portraits")
    assert(known.folder(known.position_of(skin)) == portraits and known.folder(known.position_of(mono)) == night)
    assert(known.folder(known.position_of(fresh)) == 0)
    try presets.rename_folder(store, night, "Nights")
    try presets.delete_folder(store, list, portraits)
    list.release()
    (try store.get()).close()
    store.release()
    store = try prism.Store.open(path.value)
    list = try names(store)
    known = try list.get()
    assert(known.folder_count() == 1 and known.folder_name(0) == "Nights" and known.folder_id(0) == night)
    assert(known.folder(known.position_of(skin)) == 0 and known.folder(known.position_of(mono)) == night)
    list.release()
    (try store.get()).close()
    store.release()
    print("PASS presets save, replace, rename, expose, delete, fold into folders and reopen")