Luce packages
LuceLuce BaseLuciaOS

dymokomi/luced-3d

Source of release 0.11.5

0.11.5 / tests / editor / compute_tests.luc

## Headless worker integration: real isolated Luce heap, progress and stale jobs.
from workspace import Workspace
from compute_request import RequestWriter, read_request
from network import Network
from luce_3d.graphics import Vector3
import time
import modeling_commands
import node_commands
import selection_commands

func settle(workspace: Workspace) -> unit!:
    let session = workspace.compute else trap("compute")
    let deadline = time.now() + 20000000000
    while session.busy and time.now() < deadline:
        _ = workspace.poll_compute()
    assert(not session.busy)

pub func compute_tests() -> unit!:
    let workspace = Workspace()
    node_commands.rename(workspace, "Cube %\n雪")
    let copied = read_request(RequestWriter().encode(workspace.network, 3), Network(false))
    assert(copied.require(1).name == workspace.network.require(1).name)
    workspace.enable_compute()
    settle(workspace)
    assert(workspace.notice == "")
    assert((workspace.geometry else trap("worker mesh")).face_count() == 6)
    node_commands.set_size(workspace, 3.0)
    node_commands.set_size(workspace, 4.0)
    node_commands.set_size(workspace, 5.0)
    settle(workspace)
    assert((workspace.geometry else trap("latest mesh")).bounds().maximum.y == 5.0)
    let prepared = workspace.geometry else trap("prepared worker mesh")
    assert(prepared.ray_distance(Vector3(0.0,6.0,0.0),Vector3(0.0,-1.0,0.0)) == 1.0)
    assert(prepared.surface_distance(Vector3(0.0,6.0,0.0)) == 1.0)
    let generation = (workspace.compute else trap("compute")).generation
    for mode in [4, 0, 1, 2, 3]:
        workspace.set_display_mode(mode)
        assert(not (workspace.compute else trap("compute")).busy)
        assert((workspace.compute else trap("compute")).generation == generation)
        assert((workspace.geometry else trap("cached geometry")).bounds().maximum.y == 5.0)
    workspace.undo()
    settle(workspace)
    assert((workspace.geometry else trap("undo mesh")).bounds().maximum.y == 4.0)
    # A verb with nothing to do warns across the worker and passes its input.
    node_commands.add_node(workspace, "Fill", 0.0, 120.0)
    settle(workspace)
    let fill = workspace.selected() else trap("fill node")
    assert(fill.warning != "" and fill.failure == "" and (workspace.geometry else trap("fill mesh")).face_count() == 6)
    workspace.undo()
    settle(workspace)
    # Select → tool → node on the worker: the output selection arrives with
    # the result.
    selection_commands.set_mode(workspace, 3)
    selection_commands.choose_component(workspace, 2, false)
    modeling_commands.model(workspace, "Extrude")
    settle(workspace)
    assert((workspace.geometry else trap("extruded")).face_count() == 10 and workspace.selected_ids() == [2])
    workspace.undo()
    settle(workspace)
    # Normal guides are made only while shown.
    assert(workspace.batches.normal_batch == none or (workspace.batches.normal_batch else trap("guides")).count() == 0)
    workspace.toggle_normals()
    settle(workspace)
    assert((workspace.batches.normal_batch else trap("normal guides")).count() == 6)
    workspace.toggle_normals()
    node_commands.add_node(workspace, "File", 0.0, 0.0)
    node_commands.set_text(workspace, 0, "tests/fixtures/assembly.step")
    settle(workspace)
    assert(workspace.notice == "")
    assert((workspace.batches.wire_batch else trap("CAD boundaries")).count() > 0)
    assert((workspace.batches.patch_batch else trap("persistent CAD patch boundaries")).count() > 0)
    assert((workspace.selected() else trap("File")).group_paths == ["Camera test/Lens:1/solid_37"])
    node_commands.add_node(workspace, "Tessellate", 0.0, 100.0)
    settle(workspace)
    assert(workspace.notice == "")
    assert((workspace.geometry else trap("tessellated worker mesh")).face_count() > 0)
    assert((workspace.selected() else trap("Tessellate")).group_paths == ["Camera test/Lens:1/solid_37"])
    node_commands.add_node(workspace, "Blast", 0.0, 200.0)
    node_commands.set_text(workspace, 0, "*/solid_37")
    node_commands.set_parameter(workspace, 0, 1.0)
    settle(workspace)
    assert((workspace.selected() else trap("Blast")).group_paths == ["Camera test/Lens:1/solid_37"])
    node_commands.set_parameter(workspace, 0, 0.0)
    settle(workspace)
    assert((workspace.selected() else trap("Blast")).group_paths.length == 0)
    workspace.undo()
    settle(workspace)
    assert((workspace.selected() else trap("Blast")).group_paths.length == 1)
    (workspace.compute else trap("compute")).close()
    print("PASS background DAG computation, copied snapshots, latest-wins requests, undo and CAD preview/tessellation")