Luce packages
LuceLuce BaseLuciaOS

dymokomi/luced

Source of release 0.4.1

0.4.1 / src / workspace / operations.luc

## File operations never infer overwrite permission from an earlier existence
## check. Standard exclusive creation/copy/rename makes collisions reportable.
from luce_std import files
from luce_ui import ui
import workspace.paths as paths

pub func child(directory: str, name: str) -> str!:
    if name == "" or name == "." or name == ".." or name.contains("/") or name.contains("\\") or name.contains(":"):
        error(ui.invalid, "Enter a single file or folder name")
    for character in name:
        if character < " " or character == "\u{7f}":
            error(ui.invalid, "Names cannot contain control characters")
    return paths.join(directory, name)

pub func create_file(directory: str, name: str) -> str!:
    let path = child(directory, name)
    files.create_text(path)
    return path

pub func create_folder(directory: str, name: str) -> unit!:
    files.create_directory(child(directory, name))

## Copy or move `source` into `directory`, choosing an unused name so a paste
## never clobbers an existing entry; a collision falls back to a " copy" suffix.
pub func paste(source: str, directory: str, move: bool) -> str!:
    let filename = paths.name(source)
    let dot = filename.split(".")
    let extension = "." + (dot.last else "") if dot.length > 1 and not filename.starts_with(".") else ""
    let stem = filename[..<filename.length - extension.length]
    for number in 0..<10001:
        let suffix = "" if number == 0 else (" copy" if number == 1 else f" copy {number}")
        let target = paths.join(directory, stem + suffix + extension)
        if move:
            files.rename(source, target, replace = false) catch failure:
                if failure.code == files.already_exists:
                    continue
                error(failure.code, failure.message)
        else:
            files.copy(source, target) catch failure:
                if failure.code == files.already_exists:
                    continue
                error(failure.code, failure.message)
        return target
    error(ui.invalid, "No unused destination name was found")